|
|
|
| Autor |
Správa |
inkognitto
Star
Pohlavie: 
Stav: 
Založený: 21.07.2005
Príspevky: 602
Bydlisko: KE
Karma:   
|
 Zaslal: 29 Jún 2008, 14:32 Predmet: |
  |
|
| vykon v pohode postaci do 200W na kanal |
|
| Návrat hore |
|
 |
dudo02
Medium Professional
Pohlavie:
Stav:
Založený: 23.11.2006
Príspevky: 1046
Karma:
|
| Zaslal: 29 Jún 2008, 16:47 Predmet: |
|
|
| inkognitto napísal: |
a ten Diak1 a Tri1 su nejake integrace, alebo tranzistory, ci gratzka ?
Btw, nemate niekto schemu na vykonnostny dimmer, DMX ovladatelny ?: v preklade stmievac, ktory sa ovlada externym pultom na zaklade datoveho toku a nie silnoprudom. |
Takze co mas na mysli pod pojmom"datovy tok" a 'externy pult"?Co chces stmievat? |
|
| Návrat hore |
|
|
inkognitto
Star
Pohlavie:
Stav:
Založený: 21.07.2005
Príspevky: 602
Bydlisko: KE
Karma:
|
|
| Návrat hore |
|
|
dudo02
Medium Professional
Pohlavie:
Stav:
Založený: 23.11.2006
Príspevky: 1046
Karma:
|
| Zaslal: 30 Jún 2008, 21:25 Predmet: |
|
|
Takze schemu mozes pouzit tu co tu je.Spravis to X krat,kde X=pocet kanalov ktore chces ovladat.
| Citácia: |
| no a na rozdiel medzi silnoprudom a datovym tokom staci len pouzit zdravy sedliacky rozum, to je jasne, je to zalozene na prinipe tranzistora => malym prudom ovladas velky. |
Som na to neprisiel,teda asi nemam zdravy sedliacky rozum.Co ma aj celkom tesi. 
Skus postudovat co to je logicka hodnota 1 a 0.A co ma s tym spolocne"datovy tok"..
A co znamena pojem "regulacia"u elektrickych velicin.. |
|
| Návrat hore |
|
|
inkognitto
Star
Pohlavie:
Stav:
Založený: 21.07.2005
Príspevky: 602
Bydlisko: KE
Karma:
|
| Zaslal: 01 Júl 2008, 16:42 Predmet: |
|
|
nechce sa mi robit obrazok, tak to skusim napisat.
Mas zariadenia A: Ovladaci panel, B: Vykonova jednotka, C: Spotrebič
"A" prostrednictvom 2 respektive 3 žíl dáva príkazy "B", "B" prostredíctvom 2 žil dodáva napätie do "C". Keby som tú schému dal do jednej "krabice" tak by do/z nej muselo viest: 1 dvojlinka na prívod U, (v mojom prípade) 10 dvojliniek na ovládanie zariadení. Ako by sa mi takéto hovado zmestilo na plochu 30x12x(0-8)cm
preto potrebujem nejaky externý ovládač, ktorý by bol malý a nedratoval by som ho 11 vodičmi.
no a moje vyjadrenie "datovy tok" nemozes brat vedecky exaktne, pointa je v tom, ze to nie je zalozene na silnoprude, ale na signale alebo tak podobne, na moje nestastie som nevystudoval elektrotechniku, takze tak. |
|
| Návrat hore |
|
|
dudo02
Medium Professional
Pohlavie:
Stav:
Založený: 23.11.2006
Príspevky: 1046
Karma:
|
| Zaslal: 01 Júl 2008, 20:09 Predmet: |
|
|
Na ovladaci pult namontujus len potenciometre.Od pultu potiahnes nejaky kabel 24 zil.Samotne zasuvky+elektronika bude v nejakom dalsom boxe.
BTW-co sa ti zda vela tahat 30 zilovy kabel?Pri ovladcich pultoch je beznych aj ovela vic zil.. |
|
| Návrat hore |
|
|
jasan21
Expert
Pohlavie:
Stav:
Založený: 21.04.2008
Príspevky: 181
Bydlisko: seňa
Karma: 
|
| Zaslal: 01 Júl 2008, 22:31 Predmet: |
|
|
 nechcem vas rusit v tom startreku ale ja som tu pisal o ventilatore za 600-700 korun a uz samotny potenciometer mal 2/3 cenu
dalej uz tu tahate kable ako z mochoviec....
ja som sa pytal ci bude vadit ked na ten ventilator nahodim obycajny potenciometer na regulaciu otacok a uz sa tu vyrabaju vznasadla....
PRRRRR  hosi  |
|
| Návrat hore |
|
|
inkognitto
Star
Pohlavie:
Stav:
Založený: 21.07.2005
Príspevky: 602
Bydlisko: KE
Karma:
|
| Zaslal: 02 Júl 2008, 9:54 Predmet: |
|
|
ked das na obmedzenie jednu pasivnu suciastku, teda potenciometer, tak ti to bude absorbovat rozdiel plneho vykonu a aktualne dodavaneho vykonýu, co ti po par minutach behu hoci uz aj na polovicnych otackach sposobi, ze ten potenciometer zhori, zacne tliet alebo podobne. mne sa daco obdobne stalo pri 7W a to si zober ze vrtacka ci ventilator ci co to maju dakedy aj cez 1000W.
No, spat k problemu o startreku:
no, mojo, pri DMX pulte bez vykonu sa tahaju minimalne 5 zil, maximalne podla toho aky je velky. a preco 5?: 2su na DC+- a 3 su na XLR konektor.
24 zilovy kabel, cez ktory pojde 220 na zilu, respektive 300W na zilu sa mi vidi fakt dost vela, aku by to malo hrubku ? 3-4 cm ? |
|
| Návrat hore |
|
|
dudo02
Medium Professional
Pohlavie:
Stav:
Založený: 23.11.2006
Príspevky: 1046
Karma:
|
| Zaslal: 08 Júl 2008, 19:58 Predmet: |
|
|
Troska som bol mimo..
Takze este raz-kabel bude prepajat len cisto potenciometre s plosnym spojom.Nie silovu cast-cize tam nebude tiect ziadnych 300W..Po vodici bude tiect prud,ktory bude ovladat riadiacu mriezku(bazu) triaku..Chapes?Uplne staci 0,5mm.. |
|
| Návrat hore |
|
|
inkognitto
Star
Pohlavie:
Stav:
Založený: 21.07.2005
Príspevky: 602
Bydlisko: KE
Karma:
|
| Zaslal: 11 Aug 2008, 15:34 Predmet: |
|
|
no, chapem,...
odhadom aky vykon by cez to mal ist ? aby som si vedel kupit co najtensi kabel.
+mohol by som ta poprosit a nejaku DPS, s tym ze bude vidno "vystupene" potenciometre, prosiiiiim
a este, aky vykon to znesie ?
//autoeditácia príspevku ( 11 Aug 2008, 15:34 )
pzorite sa pls na tuto schemu:
http://www.hypex.sk/Tech/Light/DMXDimm1.gif
je to jednokanalovy dmx dimmer adresovany manualne a je to celkom lahka schema (uz len najst nekoho s atmel programatorom )
no a tu je druha:
http://www.rocob.biz/vyroba/dim4_sch.jpg
toto je 4 kanalovy dmx dimmer, len ta schema je kus spatlana.
Moja otazka spociva v tom, ci by sa do tej prvej schemy dali prirobit dalsie 3 kanaly tak, aby to aj fungovalo (nakolko tam su este 3 volne piny). A nakolko tomuto peknemu jazyku nerozumiem, tak by som aj cel vediet ci to program rozpisany nizsie "ovlada"
| Kód: |
Program pre AT89C2051
$MOD51
$TITLE(DMX 4ch Dimmer V.1.3)
$NOPAGING
$DEBUG
; AT89C2051
; P1.0 .. P1.7 - DMX Start Adress, 0 to 255 on DIPsw = 1 to 256 start adress
; P3.0 - RXD from SN75176
; P3.1 - PWM trigger out ch1
; P3.2 - Zero detector input
; P3.3 - PWM trigger out ch2
; P3.4 - PWM trigger out ch3
; P3.5 - PWM trigger out ch4
; P3.7 - Status LED
; Variables Description ==========================================================
DMX1 DATA 030h ; 4 prijimane DMX slotoy
DMX2 DATA 031h
DMX3 DATA 032h
DMX4 DATA 033h
Ch1 DATA 035h ; linearizovanzy SinusPWM vykon 0..100%
Ch2 DATA 036h
Ch3 DATA 037h
Ch4 DATA 038h
DErr DATA 03Ah
Delay DATA 03Bh
Slot DATA 03Dh ; Cislo prave prijimaneho DMX slotu
SlotNo DATA 03Eh ; Pocet prijatych slotov (0..3)
Addr DATA 03Fh ; Pociatocna DMX adresa z DIP switch
Break BIT 000h ; Zachyteny DMX Break, caka sa na StartCode=0
; Interrupt vectors ==============================================================
ORG 0000h ; Po resete
AJMP INIT ; Nastav IO
NOP
ORG 0003h ; Vektor od vstupu prerusenia - Zachytenie konca prechodu nulou
MOV R1,#99 ;1 Ak bol zachyteny prechod 0, odstartuj nove odpocitavanie do dalsiecho prechodu 0
MOV TL0,#127 ;2 Inicializacia casovaca
SETB P3.7 ;1 Reset chyby cakania na nulu v sieti
; CLR EX0 ;2 zakazanie externeho prerusenia 0 na dobeznu hranu
RETI ;2 Navrat z prerusenia
ORG 000Bh ; Vektor prerusenia casovaca TF0
AJMP iTF0
NOP
; DMX512A Serial Communication ===================================================
ORG 0023h ; Vektor prerusenia od serioveho kanalu RI+TI
PUSH ACC ;2 Ulozenie menenych registrov do zasobnika
PUSH PSW ;2
CLR RI ;1 Nulovanie priznaku prijateho slova
JB RB8,OkSlot ;2 Ak je platny bit8=1 tak je to platny Slot, inak DMX Break
JB P3.0,DMXErr ;2 Ak je na vstupnej linke log 1 je DMX Error
MOV A,SBUF ;1 Break test
JNZ DMXErr ;2 Ak su Data nenulove, neni Break, je to len DMX Error
JB P3.0,DMXErr ;2 Ak je na vstupnej linke log 1 je DMX Error
MOV Slot,#0 ;2 Ak bol Break, vynuluj citac prijatych slotov
MOV SlotNo,#0 ;2 Nuluj pocet nacitanych DMX slov
SETB Break ;1 Zapni cakanie na DMX StartCode
POP PSW ;2 Obnovenie registrov zo zasobnika
POP ACC ;2
RETI ;2 po beraku 25clk Navrat z prerusenia
OkSlot: JNB Break,DSlot ;2 Ak sa necaka na StartCode preskoc
MOV A,SBUF ;1 Nacitanie prijateho start kodu
JNZ DMXErr ;2 StartCode po Breaku je nenulovy, DMX Error, cakaj na dalsi Break
CLR Break ;1 StartCode=0 Ok, dalsie data su postupne datove DMX sloty
MOV DErr,#255 ;2 Reset chyby DMX signalu
MOV A,P1 ;1 Nacitaj DMX adresu z DIP Switchu
CPL A ;1 Neguj adresu, DIPswitvh spina do 0
MOV Addr,A ;1 Uloz bity predvolenej DMX adresy
POP PSW ;2 Obnovenie registrov zo zasobnika
POP ACC ;2
RETI ;2 po start code 24clk Navrat z prerusenia
DMXErr: MOV SlotNo,#4 ;2 Cakaj na dalsi Break ak nezachytilo StartCode
POP PSW ;2 Obnovenie registrov zo zasobnika
POP ACC ;2
RETI ;2 pri chybe max 22clk Navrat z prerusenia
DSlot: MOV A,SlotNo ;1 10
CJNE A,#4,TstNxt ;2 Ak sa nenacitalo potrebny pocet slotov tak testuj
POP PSW ;2 Obnovenie registrov zo zasobnika
POP ACC ;2
RETI ;2 18clk Navrat z prerusenia
TstNxt: JNZ RecNxt ;2 Ak sa nacital prvy tak nacitaj este druhy a treti
MOV A,Slot ;1
CJNE A,Addr,NextS ;2 Cakaj na potrebnu adresu slotu
RecNxt: MOV A,SlotNo ;1 Nacitanie data slotu
ADD A,#030h ;1 Naplnenie adries 30h,31h,32h,33h hodnotami z DMX linky
MOV R0,A ;1
MOV @R0,SBUF ;2 Save Data Slot
INC SlotNo ;2
POP PSW ;2 Obnovenie registrov zo zasobnika
POP ACC ;2
RETI ;2 27clk Navrat z prerusenia
NextS: INC Slot ;2 Zvysit prijatu DMX adresu
POP PSW ;2 Obnovenie registrov zo zasobnika
POP ACC ;2
RETI ;2 25clk Navrat z prerusenia
NOP
; End of DMX512A Serial Communication ============================================
; Fazova regulacia ===============================================================
iTF0: PUSH ACC ;2 Ulozenie menenych registrov do zasobnika
PUSH PSW ;2
DJNZ R1,Trig ;2 Ak prebieha odpocitavanie do konca polperiody sinusovky, reguluj PWM triakmi
SETB P3.1 ;1 Ak je ocakavany prechod nulou (0.0099s)
SETB P3.3 ;1 Zatvaranie triakov pred prechodom nulou
SETB P3.4 ;1
SETB P3.5 ;1
; SETB EX0 ;1 povolenie externeho prerusenia 0 na dobeznu hranu
INC R1 ;1 Ak je nula sprav +1, zostane visien na nule
CLR P3.7 ;1 LED chyba cakania na nulu v sieti
POP PSW ;2
POP ACC ;2 Obnovenie registrov zo zasobnika
RETI ;2 Navrat z prerusenia 18 cyklov
Trig:
MOV A,Ch1 ;1 Fazova regulacia Ch1
SETB C ;1 Porovnanie ziadanej hodnoty Ch1 s fazovym odpocitavanim
SUBB A,R1 ;1
MOV P3.1,C ;1 Nastavenie vystupu pre optotriak Ch1
MOV A,Ch2 ;1 Fazova regulacia Ch2
SETB C ;1 Porovnanie ziadanej hodnoty Ch2 s fazovym odpocitavanim
SUBB A,R1 ;1
MOV P3.3,C ;1 Nastavenie vystupu pre optotriak Ch2
MOV A,Ch3 ;1 Fazova regulacia Ch3
SETB C ;1 Porovnanie ziadanej hodnoty Ch3 s fazovym odpocitavanim
SUBB A,R1 ;1
MOV P3.4,C ;1 Nastavenie vystupu pre optotriak Ch3
MOV A,Ch4 ;1 Fazova regulacia Ch4
SETB C ;1 Porovnanie ziadanej hodnoty Ch4 s fazovym odpocitavanim
SUBB A,R1 ;1
MOV P3.5,C ;1 Nastavenie vystupu pre optotriak Ch4
POP PSW ;2
POP ACC ;2 Obnovenie registrov zo zasobnika
RETI ;2 Navrat z prerusenia 29 cyklov
NOP
; Koniec fazovej regulacie =======================================================
; Device Initialisation ==========================================================
INIT: MOV P1,#0FFh ; DIP Switch Adresa
MOV P3,#0FFh ; Ostatne I/O
MOV SP,#060h ; Ukazovatel zasobniku na adrese 60h az 7Fh
MOV TMOD,#00000010b ; Tim0 - 8bitovy casovac s automatickym prednastavenim, mod 2 (Fosc/12)/THn
MOV TCON,#00010001b ; Povolenie casovaca 0 a prerusenia 0
MOV TH0,#127 ; 10256Hz / 100 = 10256Hz -> 2x 1/2 sine wave
MOV TL0,#0 ; 256 - ( 16 000 000 / 12 ) / 10256 = 126
MOV SlotNo,#4 ; Nastavenie pociatocneho cakania na DMX512 Break
MOV PCON,#00000000b ; Rychlost seriovky 16MHz/64=250kb (DMX512A 1998 USITT)
MOV SCON,#10011000b ; Seriovy kanal v rezime 2 - 9bit UART - prijem
MOV DMX1,#0
MOV DMX2,#0
MOV DMX3,#0
MOV DMX4,#0
MOV P1,#0FFh ; DIP Switch Adresa
MOV P3,#0FFh ; Ostatne I/O
MOV IP,#00010001b ; Nastavenie poradia preruseni, najvyssie pExt0, potom seriovka a fazova regulacia
MOV IE,#10010011b ; Povolenie prerusena od seriovky, casovaca 0 a prerusenie 0 na dobeznu hranu
; Hlavna slucka ========================================================================
; Tento program bezi v zbytkovom case procesora sucastne s automatickym prijimom DMX a Fazovou regulaciou
Loop:
MOV A,DMX1 ; Linearizacia vykonu, vstup hodnota 0..255, vystup 0..100%
MOV DPTR,#0200h
MOVC A,@A+DPTR
ADD A,#6 ; predzhavenie 9 az 16
MOV Ch1,A
MOV A,DMX2 ; Linearizacia vykonu, vstup hodnota 0..255, vystup 0..100%
MOV DPTR,#0200h
MOVC A,@A+DPTR
ADD A,#6 ; predzhavenie 9 az 16
MOV Ch2,A
MOV A,DMX3 ; Linearizacia vykonu, vstup hodnota 0..255, vystup 0..100%
MOV DPTR,#0200h
MOVC A,@A+DPTR
ADD A,#6 ; predzhavenie 9 az 16
MOV Ch3,A
MOV A,DMX4 ; Linearizacia vykonu, vstup hodnota 0..255, vystup 0..100%
MOV DPTR,#0200h
MOVC A,@A+DPTR
ADD A,#6 ; predzhavenie 9 az 16
MOV Ch4,A
DJNZ Delay,NoErr
DJNZ DErr,NoErr
CLR P3.7
INC DErr
INC Delay
NoErr:
AJMP Loop
; Koniec hlavnej slucky ================================================================
ORG 0200h ; krivka linearizacie fazovo riadeneho vykonu
Power:
DB 0,1,1,2,3,3,4,4,5,6,6,7,7,8,8,9,9,10,11,11,12,12,13,13,14,14,15,15,16,16,17,17,17,18,18,19,19,20,20,21,21,21,22,22,23,23,23,24,24,25,25,25,26,26,27,27,27,28,28,28,29,29,29,30,30,30,31,31,31,32,32,32,33,33,33,33,34,34,34,35,35,35,35,36,36,36,36,37,37;
DB 37,37,38,38,38,38,39,39,39,39,40,40,40,40,41,41,41,41,41,42,42,42,42,42,43,43,43,43,44,44,44,44,44,45,45,45,45,45,46,46,46,46,46,47,47,47,47,47,48,48,48,48,49,49,49,49,49,50,50,50,50,50,51,51,51,51,52,52,52,52,53,53,53,53,53,54,54,54,54,55,55,55,55,56;
DB 56,56,57,57,57,57,58,58,58,59,59,59,59,60,60,60,61,61,61,62,62,62,63,63,63,64,64,64,65,65,65,66,66,67,67,67,68,68,69,69,69,70,70,71,71,71,72,72,73,73,74,74,75,75,76,76,77,77,78,78,79,79,80,80,81,81,82,82,83,83,84,84,85,85,86,87,88,89,90,91,92,93,94,94;
END; Program end ==================================================================== |
THX |
|
| Návrat hore |
|
|
|
|  |
|
|
Nemôžete odosielať nové témy do tohto fóra
Nemôžete odpovedať na témy v tomto fóre
Nemôžete upravovať svoje príspevky v tomto fóre
Nemôžete mazať svoje príspevky v tomto fóre
Nemôžete hlasovať v tomto fóre
Nemôžete pripájať súbory do tohto fóra
Môžete sťahovať súbory v tomto fóre
|
Powered by phpBB © 2005 phpBB Group, phpBB SEO, © Hojko 2004-2008
[ Vygenerované za: 0.2s ] :: [ 16 Queries ] :: [ 10,602 stránok za dnes ] :: [ Dnes DB: 181,061 ] :: [ Max DB: 2,334,336 Queries ]
|
